QED manual (development version)

Load FeynCalc and the necessary add-ons or other packages

description = "El Ael -> Mu Amu, QED, total cross section, tree";
If[ $FrontEnd === Null, 
    $FeynCalcStartupMessages = False; 
    Print[description]; 
  ];
If[ $Notebooks === False, 
    $FeynCalcStartupMessages = False 
  ];
$LoadAddOns = {"FeynArts"};
<< FeynCalc`
$FAVerbose = 0; 
 
FCCheckVersion[9, 3, 1];

FeynCalc   10.0.0 (dev version, 2023-12-20 22:40:59 +01:00, dff3b835). For help, use the online  documentation‾  , check out the wiki‾   or visit the forum.‾\text{FeynCalc }\;\text{10.0.0 (dev version, 2023-12-20 22:40:59 +01:00, dff3b835). For help, use the }\underline{\text{online} \;\text{documentation}}\;\text{, check out the }\underline{\text{wiki}}\;\text{ or visit the }\underline{\text{forum}.}

Please check our FAQ‾   for answers to some common FeynCalc questions and have a look at the supplied examples.‾\text{Please check our }\underline{\text{FAQ}}\;\text{ for answers to some common FeynCalc questions and have a look at the supplied }\underline{\text{examples}.}

If you use FeynCalc in your research, please evaluate FeynCalcHowToCite[] to learn how to cite this software.\text{If you use FeynCalc in your research, please evaluate FeynCalcHowToCite[] to learn how to cite this software.}

Please keep in mind that the proper academic attribution of our work is crucial to ensure the future development of this package!\text{Please keep in mind that the proper academic attribution of our work is crucial to ensure the future development of this package!}

FeynArts   3.11 (3 Aug 2020) patched for use with FeynCalc, for documentation see the manual‾   or visit www.feynarts.de.‾\text{FeynArts }\;\text{3.11 (3 Aug 2020) patched for use with FeynCalc, for documentation see the }\underline{\text{manual}}\;\text{ or visit }\underline{\text{www}.\text{feynarts}.\text{de}.}

If you use FeynArts in your research, please cite\text{If you use FeynArts in your research, please cite}

 ∙ T. Hahn, Comput. Phys. Commun., 140, 418-431, 2001, arXiv:hep-ph/0012260\text{ $\bullet $ T. Hahn, Comput. Phys. Commun., 140, 418-431, 2001, arXiv:hep-ph/0012260}

Generate Feynman diagrams

Nicer typesetting

MakeBoxes[p1, TraditionalForm] := "\!\(\*SubscriptBox[\(p\), \(1\)]\)";
MakeBoxes[p2, TraditionalForm] := "\!\(\*SubscriptBox[\(p\), \(2\)]\)";
MakeBoxes[k1, TraditionalForm] := "\!\(\*SubscriptBox[\(k\), \(1\)]\)";
MakeBoxes[k2, TraditionalForm] := "\!\(\*SubscriptBox[\(k\), \(2\)]\)";
diags = InsertFields[CreateTopologies[0, 2 -> 2], {F[2, {1}], -F[2, {1}]} -> 
            {F[2, {2}], -F[2, {2}]}, InsertionLevel -> {Classes}, 
            Restrictions -> QEDOnly]; 
 
Paint[diags, ColumnsXRows -> {1, 1}, Numbering -> Simple, 
    SheetHeader -> None, ImageSize -> {256, 256}];

174iss4d43u6t

Obtain the amplitude

amp[0] = FCFAConvert[CreateFeynAmp[diags], IncomingMomenta -> {p1, p2}, 
    OutgoingMomenta -> {k1, k2}, UndoChiralSplittings -> True, ChangeDimension -> 4, 
    List -> False, SMP -> True, Contract -> True]

−e2(φ(−p2‾,me)).γˉLor1.(φ(p1‾,me))(φ(k1‾,mμ)).γˉLor1.(φ(−k2‾,mμ))(k1‾+k2‾)2-\frac{\text{e}^2 \left(\varphi (-\overline{p_2},m_e)\right).\bar{\gamma }^{\text{Lor1}}.\left(\varphi (\overline{p_1},m_e)\right) \left(\varphi (\overline{k_1},m_{\mu })\right).\bar{\gamma }^{\text{Lor1}}.\left(\varphi (-\overline{k_2},m_{\mu })\right)}{(\overline{k_1}+\overline{k_2}){}^2}

Polarized production: the particles are right-handed, while the antiparticles are left-handed

ampPolarized[0] = amp[0] /. {
    Spinor[-Momentum[k2], r__] :> 
            GA[6] . Spinor[-Momentum[k2], r], 
    Spinor[Momentum[k1], r__] :> 
            Spinor[Momentum[k1], r] . GA[7], 
    Spinor[Momentum[p1], r__] :> 
            GA[6] . Spinor[Momentum[p1], r], 
    Spinor[-Momentum[p2], r__] :> 
            Spinor[Momentum[p2], r] . GA[7] 
   }

−e2(φ(p2‾,me)).γˉ7.γˉLor1.γˉ6.(φ(p1‾,me))(φ(k1‾,mμ)).γˉ7.γˉLor1.γˉ6.(φ(−k2‾,mμ))(k1‾+k2‾)2-\frac{\text{e}^2 \left(\varphi (\overline{p_2},m_e)\right).\bar{\gamma }^7.\bar{\gamma }^{\text{Lor1}}.\bar{\gamma }^6.\left(\varphi (\overline{p_1},m_e)\right) \left(\varphi (\overline{k_1},m_{\mu })\right).\bar{\gamma }^7.\bar{\gamma }^{\text{Lor1}}.\bar{\gamma }^6.\left(\varphi (-\overline{k_2},m_{\mu })\right)}{(\overline{k_1}+\overline{k_2}){}^2}

Fix the kinematics

FCClearScalarProducts[];
SetMandelstam[s, t, u, p1, p2, -k1, -k2, SMP["m_e"], SMP["m_e"], 
    SMP["m_mu"], SMP["m_mu"]];

Square the amplitude

ampSquared[0] = (amp[0] (ComplexConjugate[amp[0]])) // 
        FeynAmpDenominatorExplicit // FermionSpinSum[#, ExtraFactor -> 1/2^2] & // 
    DiracSimplify // Simplify

2  e4(2me2(2mμ2+s−t−u)+2me4+2mμ4+2mμ2(s−t−u)+t2+u2)s2\frac{2 \;\text{e}^4 \left(2 m_e^2 \left(2 m_{\mu }^2+s-t-u\right)+2 m_e^4+2 m_{\mu }^4+2 m_{\mu }^2 (s-t-u)+t^2+u^2\right)}{s^2}

ampSquaredPolarized[0] = 
    (ampPolarized[0] (ComplexConjugate[ampPolarized[0]])) // 
        FeynAmpDenominatorExplicit // FermionSpinSum // DiracSimplify //Simplify

4  e4(me2+mμ2−u)2s2\frac{4 \;\text{e}^4 \left(m_e^2+m_{\mu }^2-u\right){}^2}{s^2}

ampSquaredMassless1[0] = ampSquared[0] // ReplaceAll[#, {
        SMP["m_e"] -> 0}] &

2  e4(2mμ4+2mμ2(s−t−u)+t2+u2)s2\frac{2 \;\text{e}^4 \left(2 m_{\mu }^4+2 m_{\mu }^2 (s-t-u)+t^2+u^2\right)}{s^2}

ampSquaredMassless2[0] = ampSquared[0] // ReplaceAll[#, {
        SMP["m_e"] -> 0, SMP["m_mu"] -> 0}] & // Simplify

2  e4(t2+u2)s2\frac{2 \;\text{e}^4 \left(t^2+u^2\right)}{s^2}

ampSquaredPolarizedMassless[0] = ampSquaredPolarized[0] // ReplaceAll[#, {
        SMP["m_e"] -> 0, SMP["m_mu"] -> 0}] & // Simplify

4  e4u2s2\frac{4 \;\text{e}^4 u^2}{s^2}

Total cross-section

The differential cross-section d sigma/ d Omega is given by

prefac1 = 1/(64 Pi^2 s);
integral1 = (Factor[ampSquaredMassless2[0] /. {t -> -s/2 (1 - Cos[Th]), u -> -s/2 (1 + Cos[Th]), 
      SMP["e"]^4 -> (4 Pi SMP["alpha_fs"])^2}])

16π2α2(cos⁡2(Th)+1)16 \pi ^2 \alpha ^2 \left(\cos ^2(\text{Th})+1\right)

diffXSection1 = prefac1 integral1

α2(cos⁡2(Th)+1)4s\frac{\alpha ^2 \left(\cos ^2(\text{Th})+1\right)}{4 s}

The differential cross-section d sigma/ d t d phi is given by

prefac2 = 1/(128 Pi^2 s)

1128π2s\frac{1}{128 \pi ^2 s}

integral2 = Simplify[ampSquaredMassless2[0]/(s/4) /. 
    {u -> -s - t, SMP["e"]^4 -> (4 Pi SMP["alpha_fs"])^2}]

128π2α2(s2+2st+2t2)s3\frac{128 \pi ^2 \alpha ^2 \left(s^2+2 s t+2 t^2\right)}{s^3}

diffXSection2 = prefac2 integral2

α2(s2+2st+2t2)s4\frac{\alpha ^2 \left(s^2+2 s t+2 t^2\right)}{s^4}

The total cross-section. We see that integrating both expressions gives the same result

2 Pi Integrate[diffXSection1 Sin[Th], {Th, 0, Pi}]

4πα23s\frac{4 \pi \alpha ^2}{3 s}

crossSectionTotal = 2 Pi Integrate[diffXSection2, {t, -s, 0}]

4πα23s\frac{4 \pi \alpha ^2}{3 s}

Check the final results

knownResults = {
    (8 SMP["e"]^4 (SP[p1, k1] SP[p2, k2] + SP[p1, k2] SP[p2, k1] + 
            SMP["m_mu"]^2 SP[p1, p2]))/(SP[p1 + p2])^2 // ExpandScalarProduct // 
        ReplaceAll[#, SMP["m_e"] -> 0] &, 
    (16 SMP["e"]^4 (SP[p1, k2] SP[p2, k1]))/(SP[p1 + p2])^2, 
    ((8 SMP["e"]^4/s^2) ((t/2)^2 + (u/2)^2)), (4*Pi*SMP["alpha_fs"]^2)/(3*s) 
   };
FCCompareResults[{ampSquaredMassless1[0], ampSquaredPolarized[0], 
    ampSquaredMassless2[0], crossSectionTotal}, knownResults, 
   Text -> {"\tCompare to Peskin and Schroeder, An Introduction to QFT, Eqs 5.10, 5.21, 5.70 and to Field, Applications of Perturbative QCD, Eq. 2.1.14", 
     "CORRECT.", "WRONG!"}, Interrupt -> {Hold[Quit[1]], Automatic}];
Print["\tCPU Time used: ", Round[N[TimeUsed[], 4], 0.001], " s."];

\tCompare to Peskin and Schroeder, An Introduction to QFT, Eqs 5.10, 5.21, 5.70 and to Field, Applications of Perturbative QCD, Eq. 2.1.14  CORRECT.\text{$\backslash $tCompare to Peskin and Schroeder, An Introduction to QFT, Eqs 5.10, 5.21, 5.70 and to Field, Applications of Perturbative QCD, Eq. 2.1.14} \;\text{CORRECT.}

\tCPU Time used: 22.194 s.\text{$\backslash $tCPU Time used: }22.194\text{ s.}